Initial commit

Torque/SDK/example/tutorial.base/client/default.bind.cs

@@ -0,0 +1,232 @@
+//-----------------------------------------------------------------------------
+// Torque Game Engine 
+// Copyright (C) GarageGames.com, Inc.
+//-----------------------------------------------------------------------------
+
+
+//------------------------------------------------------------------------------
+// Key bindings for the in-game action Map
+//------------------------------------------------------------------------------
+
+if ( isObject( moveMap ) )
+   moveMap.delete();
+new ActionMap(moveMap);
+
+//------------------------------------------------------------------------------
+// Misc. in-game keys
+
+function escapeFromGame()
+{
+   if ( $Server::ServerType $= "SinglePlayer" )
+      MessageBoxYesNo( "Quit Mission", "Exit from this Mission?", "disconnect();", "");
+   else
+      MessageBoxYesNo( "Disconnect", "Disconnect from the server?", "disconnect();", "");
+}
+
+moveMap.bindCmd(keyboard, "escape", "", "escapeFromGame();");
+
+
+//------------------------------------------------------------------------------
+// Movement Keys
+
+$movementSpeed = 1; // m/s
+
+function setSpeed(%speed)
+{
+   if(%speed)
+      $movementSpeed = %speed;
+}
+
+function moveleft(%val)
+{
+   $mvLeftAction = %val * $movementSpeed;
+}
+
+function moveright(%val)
+{
+   $mvRightAction = %val * $movementSpeed;
+}
+
+function moveforward(%val)
+{
+   $mvForwardAction = %val * $movementSpeed;
+}
+
+function movebackward(%val)
+{
+   $mvBackwardAction = %val * $movementSpeed;
+}
+
+function moveup(%val)
+{
+   $mvUpAction = %val * $movementSpeed;
+}
+
+function movedown(%val)
+{
+   $mvDownAction = %val * $movementSpeed;
+}
+
+function turnLeft( %val )
+{
+   $mvYawRightSpeed = %val ? $Pref::Input::KeyboardTurnSpeed : 0;
+}
+
+function turnRight( %val )
+{
+   $mvYawLeftSpeed = %val ? $Pref::Input::KeyboardTurnSpeed : 0;
+}
+
+function panUp( %val )
+{
+   $mvPitchDownSpeed = %val ? $Pref::Input::KeyboardTurnSpeed : 0;
+}
+
+function panDown( %val )
+{
+   $mvPitchUpSpeed = %val ? $Pref::Input::KeyboardTurnSpeed : 0;
+}
+
+function getMouseAdjustAmount(%val)
+{
+   // based on a default camera fov of 90'
+   return(%val * ($cameraFov / 90) * 0.01);
+}
+
+function yaw(%val)
+{
+   $mvYaw += getMouseAdjustAmount(%val);
+}
+
+function pitch(%val)
+{
+   $mvPitch += getMouseAdjustAmount(%val);
+}
+
+function jump(%val)
+{
+   $mvTriggerCount2++;
+}
+
+function mouseTrigger(%val)
+{
+   $mvTriggerCount0++;
+}
+
+moveMap.bind( keyboard, a, moveleft );
+moveMap.bind( keyboard, d, moveright );
+moveMap.bind( keyboard, w, moveforward );
+moveMap.bind( keyboard, s, movebackward );
+moveMap.bind( keyboard, space, jump );
+
+moveMap.bind( mouse, xaxis, yaw );
+moveMap.bind( mouse, yaxis, pitch );
+moveMap.bind( mouse, button0, mouseTrigger );
+
+
+//------------------------------------------------------------------------------
+// Camera & View functions
+
+function toggleFreeLook( %val )
+{
+   if ( %val )
+      $mvFreeLook = true;
+   else
+      $mvFreeLook = false;
+}
+
+$firstPerson = true;
+function toggleFirstPerson(%val)
+{
+   if (%val)
+   {
+      $firstPerson = !$firstPerson;
+      ServerConnection.setFirstPerson($firstPerson);
+   }
+}
+
+function toggleCamera(%val)
+{
+   if (%val)
+      commandToServer('ToggleCamera');
+}
+
+moveMap.bind( keyboard, z, toggleFreeLook );
+moveMap.bind(keyboard, tab, toggleFirstPerson );
+moveMap.bind(keyboard, "alt c", toggleCamera);
+
+
+//------------------------------------------------------------------------------
+// Helper functions used by the mission editor
+
+function dropCameraAtPlayer(%val)
+{
+   if (%val)
+      commandToServer('dropCameraAtPlayer');
+}
+
+function dropPlayerAtCamera(%val)
+{
+   if (%val)
+      commandToServer('DropPlayerAtCamera');
+}
+
+moveMap.bind(keyboard, "F8", dropCameraAtPlayer);
+moveMap.bind(keyboard, "F7", dropPlayerAtCamera);
+
+
+//------------------------------------------------------------------------------
+// Key bindings for the Global action map available everywhere
+//------------------------------------------------------------------------------
+
+//------------------------------------------------------------------------------
+// Misc.
+
+GlobalActionMap.bind(keyboard, "tilde", toggleConsole);
+GlobalActionMap.bindCmd(keyboard, "alt enter", "", "toggleFullScreen();");
+
+
+//------------------------------------------------------------------------------
+// Dubuging Functions
+
+$MFDebugRenderMode = 0;
+function cycleDebugRenderMode(%val)
+{
+   if (!%val)
+      return;
+
+   if (getBuildString() $= "Debug")
+   {
+      if($MFDebugRenderMode == 0)
+      {
+         // Outline mode, including fonts so no stats
+         $MFDebugRenderMode = 1;
+         GLEnableOutline(true);
+      }
+      else if ($MFDebugRenderMode == 1)
+      {
+         // Interior debug mode
+         $MFDebugRenderMode = 2;
+         GLEnableOutline(false);
+         setInteriorRenderMode(7);
+         showInterior();
+      }
+      else if ($MFDebugRenderMode == 2)
+      {
+         // Back to normal
+         $MFDebugRenderMode = 0;
+         setInteriorRenderMode(0);
+         GLEnableOutline(false);
+         show();
+      }
+   }
+   else
+   {
+      echo("Debug render modes only available when running a Debug build.");
+   }
+}
+
+GlobalActionMap.bind(keyboard, "F9", cycleDebugRenderMode);
+
+
+